"RUN A1": What was the Apple //e loader where you had to type it?

Should be a snap to write something like that in BASIC.

I don't currently have access to my Apple disks, but I have a few different 'HELLO' programs that list what is on the disk and lets you load and run by various means (select by number, by cursor, etc...). I won't be back for 4 weeks, so I hope someone can help out.

Yeah... I think that was a fairly common boot loader with some hacked games in the 80's... let me look

Check this out... sorry about formatting... but you can have it all together in a few minutes!

10 TEXT : HOME : NORMAL
62500 D$ = CHR$ (4)
62502 PRINT ""
62505 TEXT : HOME : NORMAL : PRINT D$;"CATALOG":B = PEEK (27) - 2: IF B > 22 THEN B = 22
62510 T = 0:CH = 4: FOR CV = 0 TO 23: GOSUB 62640: IF C < > 160 THEN POKE P - 1,219: POKE P,T + 193: POKE P + 1,221:T = T + 1:S = CV
62520 NEXT CV: VTAB 24:A$ = "TYPE LETTER TO RUN, OR LOAD=1 LOCK=2 UNLOCK=3 DELETE=4 EXIT=5...."
62530 B$ = "RUN": HTAB 1: PRINT LEFT$ (A$,39);:A$ = MID$ (A$,2) + LEFT$ (A$,1):K = PEEK ( - 16384): IF K < 128 THEN FOR K = 1 TO 75: NEXT K:K = FRE (0): GOTO 62530
62540 POKE - 16368,0:K = K - 176: IF K < 1 OR K > 5 THEN 62610
62550 HTAB 1: CALL - 868: IF K = 5 THEN END
62560 PRINT " PRESS 'LETTER' YOU WISH TO ";: IF K = 1 THEN B$ = "LOAD"
62570 IF K = 2 THEN B$ = "LOCK"
62580 IF K = 3 THEN B$ = "UNLOCK"
62590 IF K = 4 THEN B$ = "DELETE": FLASH
62600 PRINT B$;: CALL - 198: NORMAL : GET K$:K = ASC (K$) - 48
62610 IF K < 17 OR K > T + 16 THEN 62530
62620 CH = 1:CV = S - T + K - 16: GOSUB 62640: IF C = 194 AND (B$ = "RUN" OR B$ = "LOAD") THEN B$ = "B" + B$
62630 FOR CH = 6 TO 39: GOSUB 62640:B$ = B$ + CHR$ (C): NEXT CH: HTAB 1: CALL - 868: PRINT B$: PRINT D$;B$: GOTO 62500
62640 CV=CV/8: C1 = INT CV:C2 = CV - C1 * 8:P = 1024 + 128 * C2 + 40 * C1 + CH:C = PEEK (P): RETURN

I found it on the Choplifter disk... I hope its what your after!

Here is an improved line 62640:
62640 C1 = INT (CV / 8):C2 = CV - C1 * 8:P = 1024 + 128 * C2 + 40 * C1 + CH:C = PEEK (P): RETURN

http://mirrors.apple2.org.za/ftp.apple.asimov.net/images/games/action/choplifter.dsk

From now on, let's just use the shorthand "it's on Asimov" and you'll know what we mean. It will be important for most any question starting with "do you know where I can find..."

If seeking for that kind of hello program
( and that is not limited to the disk of choplifter )
you´d be better by searching for the Utility City Disk from Beagle Brothers at:
http://beagle.applearchives.com/the_software/vintage_beagle_bros_softwar/utility_city.html#previous-photo
and after extraction of the zip-disk to diskimage on the disk the File "Key Cat"
look at description file for explenation
they published similar variations of hello programs.....
like the enhanced version from "Tip Disk 1"
so i´d recommend also to read the manuals / descriptions of the disks also availiable at that site....

speedyG

That line modification was from me... the first time I posted it, it turned part of it into a smiley face... and the formatting was screwed up. I didn't know how to change it so I changed the line, fixed the formatting and reposted it... glad it worked for you!