Applesoft II BASIC Programming

4 posts / 0 new
Last post
Offline
Last seen: 12 years 4 months ago
Joined: Oct 21 2011 - 00:17
Posts: 4
Applesoft II BASIC Programming

Hi, I'm still new to this site but I'm finding it very useful.

IS this a good site to ask BASIC programming questions on? If not, can anyone recommend a site that is good for this? I'm working specifically with an Apple II Plus, Applesoft II BASIC, if that matters.

One question I have is: how do you know how large (in bytes) your BASIC program is in memory? And how do you know at what memory address the program starts at?

Thanks!

gsmcten's picture
Offline
Last seen: 5 years 8 months ago
Joined: Oct 4 2005 - 18:52
Posts: 2629
Re: Applesoft II BASIC Programming

dvan,

Do you have any of the Basic Manuals?
If not, go here:
http://www.1000bit.it/support/manuali/manuali.asp

Smile

Dog Cow's picture
Offline
Last seen: 4 years 10 months ago
Joined: Dec 11 2008 - 16:26
Posts: 554
Re: Applesoft II BASIC Programming


IS this a good site to ask BASIC programming questions on? If not, can anyone recommend a site that is good for this?

Yes, this is a good site.

You can also ask on the Usenet newsgroup, comp.sys.apple2.programmer

There is a web interface to this newsgroup at Mac GUI.

And how do you know at what memory address the program starts at?

Applesoft programs start at $800.

(Which is why they get wiped out when booting DOS)

mmphosis's picture
Offline
Last seen: 3 days 13 hours ago
Joined: Aug 18 2005 - 16:26
Posts: 433
Re: Applesoft II BASIC Programming

100 HOME
110 PRINT "APPLESOFT BASIC"
120 PRINT
130 POKE 768,165: POKE 770,76
140 POKE 771,218: POKE 772,253
150 READ A,S$,T$
160 PRINT "$";
170 POKE 769,A + 1: CALL 768
180 POKE 769,A: CALL 768
190 PRINT " ";
210 PRINT A"-"A + 1;
230 POKE 769,250
240 PRINT " $";
250 POKE 250,A: CALL 768
260 PRINT "-$";
270 POKE 250,A + 1: CALL 768
280 PRINT : PRINT TAB( 7);
290 PRINT S$ " " T$
300 IF A < > 115 THEN 150
310 PRINT
320 CLEAR
330 IF FRE (0) < 0 GOTO 360
340 PRINT FRE (0);
350 GOTO 380
360 PRINT FRE (0) + 65536;
380 PRINT " BYTES FREE.";
390 END
400 DATA103
410 DATA"START OF"
420 DATA"PROGRAM"
450 DATA175
460 DATA"END OF"
470 DATA"APPLESOFT PROGRAM"
500 DATA105
510 DATA"LOMEM: START OF"
520 DATA"VARIABLE SPACE"
600 DATA107
610 DATA"START OF"
620 DATA"ARRAY SPACE"
700 DATA109
710 DATA"END OF"
720 DATA"ARRAY SPACE"
800 DATA111
810 DATA"START OF"
820 DATA"STRING STORAGE"
900 DATA115
910 DATA"HIMEM"
920 DATA"+ 1"

Log in or register to post comments